## Approximate Methods: Rayleigh Ritz Method

The Rayleigh Ritz method is a classical approximate method to find the displacement function of an object such that the it is in equilibrium with the externally applied loads. It is regarded as an ancestor of the widely used Finite Element Method (FEM). The Rayleigh Ritz method relies on the principle of minimum potential energy for conservative systems. The method involves assuming a form or a shape for the unknown displacement functions, and thus, the displacement functions would have a few unknown parameters. These assumed shape functions are termed Trial Functions. Afterwards, the potential energy function of the system is written in terms of those few parameters, and the values of those parameters that would minimize the potential energy function of the system are calculated. Mathematically speaking, we assume that the unknown displacement function is a member of a certain space of functions; for example, we can assume that where is the set of all the possible vector valued linear functions defined on the body represented by the set . With this assumption, we restrict the possible solutions to those in the form , and thus, the unknown parameters are restricted to the matrix , which in this particular example, has nine components. Finally, the nine components that would minimize the potential-energy function are obtained. The method will be illustrated using various one-dimensional examples.

The Rayleigh Ritz method seeks to find an approximate solution to minimize the potential energy of the system. For plane bars under axial loading, the unknown displacement function is . In this case, the potential energy of the system has the following form (See beams under axial loads and energy expressions):

where is Young’s modulus, is the cross sectional area, and is the work done by all the external forces acting on the bar (concentrated forces and distributed loads). To obtain an approximate solution for , a trial function of a finite number of unknowns is first selected. Then, this trial function has to satisfy the “essential” boundary conditions, which are those boundary conditions that would satisfy the physical stability of the system. In the case of bars under axial loads, the trial function has to satisfy the displacement boundary conditions. The following examples show the method for different external loads, and bar configurations.

#### Example 1: A Bar under Axial Forces

Let a bar with a length and a constant cross sectional area be aligned with the coordinate axis . Assume that the bar is subjected to a horizontal body force (in the direction of the axis ) units of force/unit length where is a known constant. Also, assume that the bar has a constant force of value applied at the end . If the bar is fixed at the end , find the displacement of the bar by directly solving the differential equation of equilibrium. Also, find the displacement function using the Rayleigh Ritz method assuming a polynomial function for the displacement of the degrees (0, 1, 2, 3, and 4). Assume that the bar is linear elastic with Young’s modulus and that the small strain tensor is the appropriate measure of strain. Ignore the effect of Poisson’s ratio.

##### Solution

Exact Solution:
First, the exact solution that would satisfy the equilibrium equations can be obtained. The equilibrium equation as shown in the beams under axial loading section when and are constant is:

Therefore, the exact solution has the form:

where and can be obtained from the boundary conditions:

Therefore, the exact solution for the displacement and the stress are:

View Mathematica Code
Clear[u, x]
a = DSolve[{u''[x] == -c*x/(Ee*A), u'[L] == P/(Ee*A), u[0] == 0}, u, x]
u = u[x] /. a[[1]]
FullSimplify[u]
sigma = Ee*D[u, x];
FullSimplify[sigma]


The Rayleigh Ritz Method:
The first step in the Rayleigh Ritz method finds the minimizer of the potential energy of the system which can be written as:

Notice that the potential energy lost by the action of the end force is equal to the product of and the displacement evaluated at while the potential energy lost by the action of the distributed body forces is an integral since it acts on each point along the beam length. Further, we will use the constitutive equation to rewrite the potential energy function in terms of the function :

To find an approximate solution, an assumption for the shape or the form of has to be introduced.
Polynomial of the Zero Degree:
First, we can assume that is a constant function (a polynomial of the zero degree):

However, to satisfy the “essential” boundary condition that when , the constant has to equal to zero; this leads to the trivial solution , which will automatically be rejected.
Polynomial of the First Degree:
As a more refined approximation, we can assume that is a linear function (a polynomial of the first degree):

To satisfy the essential boundary condition the coefficient is equal to zero. Therefore:

The strain component can be computed as follows:

Substituting into the equation for the potential energy of the system:

The only variable that can be controlled to minimize the potential energy of the system is . Therefore:

Therefore, the best linear function according to the Rayleigh Ritz method is:

A linear displacement would produce a constant stress:

Unfortunately, this solution is far from being accurate, since it does not satisfy the differential equation of equilibrium (Why?). However, within the only possible or allowed linear shapes, the obtained solution is the minimizer of the potential energy.

Polynomial of the Second Degree:
As a more refined approximation, we can assume that is a polynomial of the second degree:

To satisfy the essential boundary condition the coefficient is equal to zero. Therefore:

The strain component can be computed as follows:

Substituting into the equation for the potential energy of the system:

and are the variables that can be controlled to minimize the potential energy of the system. Therefore:

and

Solving the above two equations yields:

Therefore, the best second degree polynomial according to the Rayleigh Ritz method is:

A parabolic displacement would produce a linear stress:

View Mathematica Code
Clear[u,x,a2,a1,Ee,A,c,P,L]
u=a2*x^2+a1*x;
PE=Integrate[(1/2)*Ee*A*D[u,x]^2,{x,0,L}]-P*(u/.x->L)-Integrate[c*x*u,{x,0,L}];
Eq1=D[PE,a2]
Eq2=D[PE,a1]
s=Solve[{Eq1==0,Eq2==0},{a2,a1}]
u=u/.s[[1]]
stress=FullSimplify[Ee*D[u,x]]


Polynomial of the Third Degree:
Similarly, choosing a polynomial of the third degree as an approximate displacement function means:

with the following approximation for the axial strain

The essential boundary condition lead to . The potential energy of the system has the form:

Clearly, the method generates a large set of equations that are difficult to solve by hand. Using Mathematica we can find the values of the constants , , and that would minimize the potential energy of the system:
View Mathematica Code:

Clear[u,x,a2,a1,a3,Ee,A,c,P,L]
u=a3*x^3+a2*x^2+a1*x;
PE=Integrate[(1/2)*Ee*A*D[u,x]^2,{x,0,L}]-P*(u/.x->L)-Integrate[c*x*u,{x,0,L}];
Eq1=D[PE,a2]
Eq2=D[PE,a1]
Eq3=D[PE,a3]
s=Solve[{Eq1==0,Eq2==0,Eq3==0},{a2,a1,a3}]
u=u/.s[[1]]
stress=FullSimplify[Ee*D[u,x]]


Since the assumed trial function is a polynomial of the third degree, which is similar to the exact solution, the Rayleigh Ritz method is able to produce the exact solution for the displacement and the stresses:

#### Example 2: A Bar under Axial Forces with Varying Cross Sectional Area

Let a bar with a length 2m be aligned with the coordinate axis , and let the width of the bar be equal to 250mm while the height varies linearly such that the height is equal to 500mm when and is equal to 250mm when . Assume that the bar has a constant force of value 200N applied at the end and that the bar is fixed at the end . Find the displacement of the bar by directly solving the differential equation of equilibrium and then using the Rayleigh Ritz method assuming a polynomials of the degrees (0, 1, 2 and 3). Assume the bar to be linear elastic with Young’s modulus and assume that the small strain tensor is the appropriate measure of strain. Ignore the effect of Poisson’s ratio. Compare the solution obtained using the Rayleigh Ritz method with the exact solution.

##### Solution

Exact Solution:
First, the exact solution that would satisfy the equilibrium equations can be obtained. The equilibrium equation as shown in the beams under axial loading section when is constant and is:

The area varies linearly with according to the equation:

The two boundary conditions are:

Therefore, the exact solution for the displacement and the stress are:

Note that the exact solution for the stress could have been directly obtained by dividing the force by the variable cross sectional area. The displacement function would then be obtained by integrating the expression .
View Mathematica Code

Clear[u,x]
Ax=25/100(5/10-25/200*x);
Ee=100000;
L=2;
P=200;
s=DSolve[{Ee*u''[x]*Ax+Ee*u'[x]*D[Ax,x]==0,u'[L]==200/Ee/(Ax/.x->L),u[0]==0},u,x]
u=u[x]/.s[[1]]
stress=Ee*D[u,x]


The Rayleigh Ritz Method:
The first step in the Rayleigh Ritz method finds the minimizer of the potential energy of the system which can be written as:

Notice that the potential energy lost by the action of the end force is equal to the product of and the displacement evaluated at . Further, we will use the constitutive equation to rewrite the potential energy function in terms of the function :

To find an approximate solution, an assumption for the shape or the form of has to be introduced. Similar to the previous example, a polynomial of the zero degree cannot be used as it will automatically render the displacement .
Polynomial of the First Degree:
As a more refined approximation, we can assume that is a linear function (a polynomial of the first degree):

To satisfy the essential boundary condition the coefficient is equal to zero. Therefore:

The strain component can be computed as follows:

Substituting into the equation for the potential energy of the system:

The only variable that can be controlled to minimize the potential energy of the system is . Therefore:

Therefore, the best linear function (units of m) according to the Rayleigh Ritz method is:

A linear displacement would produce a constant stress (units of ):

Unfortunately, this solution is far from being accurate, since it does not satisfy the differential equation of equilibrium (Why?). However, within the only possible or allowed linear shapes, the obtained solution is the minimizer of the potential energy.

Polynomial of the Second Degree:
As a more refined approximation, we can assume that is a polynomial of the second degree:

To satisfy the essential boundary condition the coefficient is equal to zero. Therefore:

The strain component can be computed as follows:

Substituting into the equation for the potential energy of the system:

and are the variables that can be controlled to minimize the potential energy of the system. Therefore:

and

Solving the above two equations yields:

Therefore, the best second degree polynomial according to the Rayleigh Ritz method is:

A parabolic displacement would produce a linear stress:

Polynomial of the Third Degree:
As a more refined approximation, we can assume that is a polynomial of the third degree:

To satisfy the essential boundary condition the coefficient is equal to zero. Therefore:

The strain component can be computed as follows:

Substituting into the equation for the potential energy of the system:

, , and are the variables that can be controlled to minimize the potential energy of the system. Therefore:

Also:

And:

Solving the above three equations yields:

Therefore, the best third degree polynomial according to the Rayleigh Ritz method is:

A cubic displacement would produce a parabolic stress distribution:

View Mathematica Code
Clear[u, u1, u2, u3, u4, stress, stress1, stress2, stress3, x]
(*Exact Solution *)
Ax=25/100(5/10-25/200*x);
Ee=100000;
L=2;
P=200;
s=DSolve[{Ee*u''[x]*Ax+Ee*u'[x]*D[Ax,x]==0,u'[L]==200/Ee/(Ax/.x->L),u[0]==0},u,x]
u=u[x]/.s[[1]];
stress=Ee*D[u,x]
(*First Degree *)
u1=a1*x;
PE=Integrate[1/2*Ee*D[u1,x]^2*Ax,{x,0,L}]-P*u1/.x->L;
Eq1=D[PE,a1];
s=Solve[Eq1==0,a1];
u1=u1/.s[[1]];
stress1=Ee*D[u1,x];
(*Second Degree *)
u2=a1*x+a2*x^2;
PE=Integrate[1/2*Ee*D[u2,x]^2*Ax,{x,0,L}]-P*u2/.x-> L;
Eq1=D[PE,a1];
Eq2=D[PE,a2];
s=Solve[{Eq1==0,Eq2==0},{a1,a2}];
u2=u2/.s[[1]];
stress2=Ee*D[u2,x];
(*Third Degree *)
u3=a1*x+a2*x^2+a3*x^3;
PE=Integrate[1/2*Ee*D[u3,x]^2*Ax,{x,0,L}]-P*u3/.x->L;
Eq1=D[PE,a1];
Eq2=D[PE,a2];
Eq3=D[PE,a3];
s=Solve[{Eq1==0,Eq2==0,Eq3==0},{a1,a2,a3}];
u3=u3/.s[[1]];
stress3=Ee*D[u3,x];
(*comparison*)
Plot[{u, u1, u2, u3}, {x, 0, L}, PlotLegends -> {Style["Exact", Bold, 12], Style["u1", Bold, 12], Style["u2", Bold, 12], Style["u3", Bold, 12]}, AxesLabel -> {"X1 m", "u(m)"}, BaseStyle -> Directive[Bold, 12]]
Plot[{stress, stress1, stress2, stress3}, {x, 0, L}, AxesLabel -> {"X1 m", "stress(Pa)"}, BaseStyle -> Directive[Bold, 12], PlotLegends -> {Style["Exact", Bold, 12], Style["u1", Bold, 12],   Style["u2", Bold, 12], Style["u3", Bold, 12]}]


The exact solution obtained is a logarithmic function, while the approximations used for the Rayleigh Ritz method are polynomial functions. The Taylor series of a logarithmic function can be represented by a linear combination of polynomial functions, and so, the higher the degree of approximation, the closer the approximation to the exact solution. As seen in the plots below, good accuracy is obtained for a polynomial of the second degree for the displacement function; however, the stresses in that case have higher errors. A better approximation for the stresses is obtained using a polynomial of the third degree. In general, the error in the approximate solution (i.e., the error in ) is less than the error in its derivatives which in this case is the value of the strain component . This means as well that in order to achieve higher accuracy in the stress , higher polynomials are needed.

#### Example 3: A Bar under Varying Body Forces with Fixed Ends

Let a bar with a length 2mbe aligned with the coordinate axis , and let the cross sectional area of the bar be equal to . Assume that the bar is fixed at both ends and . Assume that the bar is subjected to a varying body force that is equal to in the direction of the coordinate axis . Find the displacement of the bar by directly solving the differential equation of equilibrium and then using the Rayleigh Ritz method assuming polynomials of the degrees (0, 1, 2, 3, and 4). Assume that the bar material is linear elastic with Young’s modulus and that the small strain tensor is the appropriate measure of strain. Ignore the effect of Poisson’s ratio. Compare the solution obtained using the Rayleigh Ritz method using three- and four-degree polynomials as approximations with the exact solution.

##### Solution

Exact Solution:
Similar to the previous examples, the equilibrium equation is:

Therefore, the solution for has the form:

The boundary conditions for this example are:

Therefore the exact solutions for the displacement (in m) and the stress (in ) are:

The Rayleigh Ritz Method:
The first step in the Rayleigh Ritz method finds the minimizer of the potential energy of the system which can be written as:

Notice that the potential energy lost by the action of the distributed body forces is an integral since it acts on each point along the beam length. Further, we will use the constitutive equation to rewrite the potential energy function in terms of the function :

To find an approximate solution, an assumption for the shape or the form of has to be introduced.
Polynomials of the Zero and First Degrees:
Assuming that that is a constant function (a polynomial of the zero degree) or a linear function (a polynomial of the first degree) and incorporating the boundary conditions:

leads to the trivial solution , which will automatically be rejected.

Polynomial of the Second Degree:
Let be a polynomial of the second degree:

The essential boundary condition can be used to find values for the constants and as follows:

Therefore, the displacement function has only one parameter that can be controlled:

The strain component can be computed as follows:

Substituting into the equation for the potential energy of the system:

can be found by minimizing the potential energy of the system. Therefore:

Therefore, the best second degree polynomial according to the Rayleigh Ritz method is:

A parabolic displacement would produce a linear stress:

Polynomials of Higher Degrees:
The results from the following Mathematica code show that the third-degree approximation is very close to the actual solution for both displacements and stresses. The polynomial of the
fourth-degree approximation is in fact exact since the exact solution is a polynomial of the fourth degree. Study the Mathematica code carefully to understand how the second boundary conditions of displacement are incorporated. The graph comparing the results are shown below.

View Mathematica Code
Clear[u, x, a1, a2, a3, a4, a5, a0, Ee, A, L, p, u3, u4]
p = 5 x^2;
s = DSolve[{Ee*u''[x] == -p/A, u[L] == 0, u[0] == 0}, u, x];
u = u[x] /. s[[1]];
stress = Ee*D[u, x];
(*Second Degree*)
u2 = a2*x^2 + a1*x;
sol = Solve[(u2 /. x -> L) == 0, a2];
u2 = u2 /. sol[[1]];
PE = 1/2*Integrate[Ee*A*D[u2, x]^2, {x, 0, L}] - Integrate[p*u2, {x, 0, L}];
Eq1 = D[PE, a1];
sol1 = Solve[{Eq1 == 0}, {a1}];
u2 = FullSimplify[u2 /. sol1[[1]]];
stress2 = FullSimplify[Ee*D[u2, x]];
(*Third Degree*)
u3 = a3*x^3 + a2*x^2 + a1*x;
sol = Solve[(u3 /. x -> L) == 0, a3];
u3 = u3 /. sol[[1]];
PE = 1/2*Integrate[Ee*A*D[u3, x]^2, {x, 0, L}] -  Integrate[p*u3, {x, 0, L}];
Eq1 = D[PE, a1];
Eq2 = D[PE, a2];
sol1 = Solve[{Eq1 == 0, Eq2 == 0}, {a2, a1}];
u3 = FullSimplify[u3 /. sol1[[1]]];
stress3 = FullSimplify[Ee*D[u3, x]];
(*Fourth Degree*)
u4 = a4*x^4 + a3*x^3 + a2*x^2 + a1*x;
sol = Solve[(u4 /. x -> L) == 0, a4];
u4 = u4 /. sol[[1]];
PE = 1/2*Integrate[Ee*A*D[u4, x]^2, {x, 0, L}] -   Integrate[p*u4, {x, 0, L}];
Eq1 = D[PE, a1];
Eq2 = D[PE, a2];
Eq3 = D[PE, a3];
sol1 = Solve[{Eq1 == 0, Eq2 == 0, Eq3 == 0}, {a1, a2, a3}];
u4 = FullSimplify[u4 /. sol1[[1]]];
stress4 = FullSimplify[Ee*D[u4, x]];
A = (25/100)^2;
Ee = 100000;
L = 2;
(*comparison*)
Plot[{u, u2, u3, u4}, {x, 0, L},  PlotLegends -> {Style["Exact", Bold, 12], Style["u2", Bold, 12],    Style["u3", Bold, 12], Style["u4", Bold, 12]},  AxesLabel -> {"X1 m", "u1(m)"}, BaseStyle -> Directive[Bold, 12]]
Plot[{stress, stress2, stress3, stress4}, {x, 0, L},  PlotLegends -> {Style["Exact", Bold, 12], Style["u2", Bold, 12],    Style["u3", Bold, 12], Style["u4", Bold, 12]},  AxesLabel -> {"X1 m", "Stress(Pa)"},  BaseStyle -> Directive[Bold, 12]]


For plane Euler Bernoulli beams under lateral loading, the unknown displacement function is . In this case, the potential energy of the system has the following form (See Euler Bernoulli Beam and energy expressions):

where is Young’s modulus, is the moment of inertia, and is the work done by all the external forces acting on the bar (concentrated forces and distributed loads). A few examples to solve for the displacements, rotations, shear forces, and moments for an Euler Bernoulli beam under lateral loading are presented in this section. Similar to the previous section, the Rayleigh Ritz method starts by choosing a form for the displacement function. This form has to satisfy the “essential” boundary conditions, which for this particular type of problems are those boundary conditions imposed on the displacements and the rotations. The following examples show the method for different external loads, and beam configurations.

#### Example 1: Cantilever Beam

Let a beam with a length and a constant cross sectional parameters area and moment of inertia be aligned with the coordinate axis . Assume that the beam is subjected to a constant force of value applied at the end in the direction shown in the figure. Assume that the bar is fixed (rotation and displacement are equal to zero) at the end . Find the displacement, rotation, bending moment, and shearing forces on the beam by directly solving the differential equation of equilibrium and then using the Rayleigh Ritz method assuming polynomials of the degrees (0,1, 2, 3, and 4). Assume the beam to be linear elastic with Young’s modulus and that the Euler Bernoulli Beam is an appropriate beam approximation.

##### Solution

Exact Solution:
First, the exact solution that would satisfy the equilibrium equations can be obtained. The equilibrium equation as shown in the Euler Bernoulli beam section when and are constant is:

For the shown cantilever beam, and therefore the exact solution for the displacement has the form:

where the constants can be obtained from the boundary conditions:

Therefore, the exact solution for the displacement , the rotation , the moment , and the shear are:

The Rayleigh Ritz Method:
The first step in the Rayleigh Ritz method finds the minimizer of the potential energy of the system which can be written as:

Notice that the potential energy lost by the action of the end force is equal to the product of ( is acting downwards and is assumed upwards) and the displacement evaluated at . To find an approximate solution, an assumption for the shape or the form of has to be introduced.
Polynomials of the Zero and First Degrees:
If we assume that is a constant (polynomial of the zero degree) or a linear (polynomial of the first degree) function, and when attempting to satisfy the essential boundary conditions:

this leads to the trivial solution , which will automatically be rejected.

Polynomial of the Second Degree:
The approximate solution forms for the displacement , the rotation , the moment , and the shear force functions if is assumed to be a polynomial of the second degree are:

To satisfy the essential boundary conditions, we have:

Therefore, the solutions forms have only one parameter that can be controlled:

Substituting into the equation of the potential energy of an Euler Bernoulli beam:

The unknown coefficient can be obtained by minimizing the potential energy:

Therefore, the “best” parabolic approximation for along with the corresponding solutions for , , and are given by:

Note that because of the simplicity of the approximation, the shear force (which is the third derivative) is always equal to zero.

Polynomial of the Third Degree:
The approximate solution forms for the displacement , the rotation , the moment , and the shear force functions if is assumed to be a polynomial of the third degree are:

To satisfy the essential boundary conditions, we have:

Therefore, the solutions forms have only two parameters and that can be controlled:

Substituting into the equation of the potential energy of an Euler Bernoulli beam:

The unknown coefficients and can be obtained by minimizing the potential energy:

Solving the above two equations yields:

Therefore, the “best” cubic approximation for along with the corresponding solutions for , , and are given by:

The “approximate” solution obtained here is identical to the “exact” solution obtained above. This is because the trial function for was assumed to be a cubic polynomial and the exact solution is in fact a cubic polynomial. One should note that when the “form” or “shape” of the approximate solution contains the “form” or “shape” of the exact solution, then the Rayleigh Ritz method renders the exact solution! To see this, we are going to try a finer approximation (A polynomial of the fourth degree).

Polynomial of the Fourth Degree:
The approximate solution forms for the displacement , the rotation , the moment , and the shear force functions if is assumed to be a polynomial of the fourth degree are:

To satisfy the essential boundary conditions, we have:

Therefore, the solutions forms have the parameters , , and that can be controlled:

Substituting into the equation of the potential energy of an Euler Bernoulli beam:

The unknown coefficients , , and can be obtained by minimizing the potential energy:

Solving the above three equations yields:

Therefore, assuming a fourth order polynomial gives the same solution as a third order polynomial!

View Mathematica Code
(*Exact Solution*)
Clear[a,x,V,M,P,y,L,EI]
M=EI*D[y[x],{x,2}];
V=EI*D[y[x],{x,3}];
th=D[y[x],x];
q=0;
M1=M/.x->0;
M2=M/.x->L;
V1=V/.x->0;
V2=V/.x->L;
y1=y[x]/.x->0;
y2=y[x]/.x->L;
th1=th/.x->0;
th2=th/.x->L;
s=DSolve[{EI*y''''[x]==q,y1==0,th1==0,V2==P,M2==0},y,x];
y=y[x]/.s[[1]]
th=D[y,x]
M=EI*D[y,{x,2}]
V=EI*D[y,{x,3}]
(*Second Degree*)
Clear[y,x,M,V,th,EI,PE]
y=a2*x^2
th=D[y,x];
M=EI*D[y,{x,2}];
V=EI*D[y,{x,3}];
PE=EI/2*Integrate[D[y,{x,2}]^2,{x,0,L}]+P*(y/.x->L);
Eq2=D[PE,a2];
Sol=Solve[{Eq2==0},{a2}]
y=y/.Sol[[1]]
th/.Sol[[1]]
FullSimplify[M/.Sol[[1]]]
FullSimplify[V/.Sol[[1]]]
(*Third Degree*)
Clear[y,x,M,V,th,EI,PE]
y=a3*x^3+a2*x^2
th=D[y,x];
M=EI*D[y,{x,2}];
V=EI*D[y,{x,3}];
PE=EI/2*Integrate[D[y,{x,2}]^2,{x,0,L}]+P*(y/.x->L);
Eq1=D[PE,a3];
Eq2=D[PE,a2];
Sol=Solve[{Eq1==0,Eq2==0},{a3,a2}]
y=y/.Sol[[1]]
th/.Sol[[1]]
FullSimplify[M/.Sol[[1]]]
FullSimplify[V/.Sol[[1]]]
(*Fourth Degree*)
Clear[y,x,M,V,th,EI,PE]
y=a4*x^4+a3*x^3+a2*x^2
th=D[y,x];
M=EI*D[y,{x,2}];
V=EI*D[y,{x,3}];
PE=EI/2*Integrate[D[y,{x,2}]^2,{x,0,L}]+P*(y/.x->L);
Eq1=D[PE,a3];
Eq2=D[PE,a2];
Eq3=D[PE,a4];
Sol=Solve[{Eq1==0,Eq2==0,Eq3==0},{a3,a2,a4}]
y=y/.Sol[[1]]
th/.Sol[[1]]
FullSimplify[M/.Sol[[1]]]
FullSimplify[V/.Sol[[1]]]


#### Example 2: Simple Beam

Let a beam with a length and a constant moment of inertia be aligned with the coordinate axis . Assume that the beam is subjected to a distributed load .(Notice that the negative sign was added since is positive when it is in the direction of positive ). Assume that the beam is hinged at the ends and . Find the displacement, rotation, bending moment, and shearing forces on the beam by directly solving the differential equation of equilibrium and then using the Rayleigh Ritz method assuming polynomials of the degrees (0, 1, 2, 3 and 4). Assume the beam to be linear elastic with Young’s modulus and that the Euler Bernoulli Beam is an appropriate beam approximation. Compare the Rayleigh Ritz method with the exact solution.

##### Solution

Exact Solution:
First, the exact solution that would satisfy the equilibrium equations can be obtained. The equilibrium equation as shown in the Euler Bernoulli beam section when and are constant is:

For the shown simple beam, and therefore the exact solution for the displacement has the form:

where the constants can be obtained from the boundary conditions:

therefore,

Therefore, the exact solution for the displacement , the rotation , the moment , and the shear are:

The Rayleigh Ritz Method:
The first step in the Rayleigh Ritz method finds the minimizer of the potential energy of the system which can be written as:

To find an approximate solution, an assumption for the shape or the form of has to be introduced.
Polynomials of the Zero and First Degrees:
If we assume that is a constant (polynomial of the zero degree) or a linear (polynomial of the first degree) function, and when attempting to satisfy the essential boundary conditions:

this leads to the trivial solution , which will automatically be rejected.

Polynomial of Higher Degrees:
Similar to the previous examples, the coefficients are obtained by first satisfying the essential boundary conditions. Then, the remaining coefficients are obtained by minimizing the potential energy of the system. As shown in the plots below, the second and third degree trial functions give the same result, while the fourth and fifth degree trial functions give the same result. The solution is shown to give the accurate result when a polynomial of the fourth or higher degree is used.

View Mathematica Code
(*Exact Solution*)
Clear[q,EI,y,x,c1,c2,c3,c4,L]
y=(q*x^4/24+c1*x^3/6+c2*x^2/2+c3*x+c4)/EI;
Eq1=y/.x-> 0;
Eq2=y/.x-> L;
Eq3=EI*D[y,{x,2}]/.x-> 0;
Eq4=EI*D[y,{x,2}]/.x-> L;
a=Solve[{Eq1==0,Eq2==0,Eq3==0,Eq4==0},{c1,c2,c3,c4}];
y=y/.a[[1]];
theta=D[y,x]/.a[[1]];
M=FullSimplify[EI*D[y,{x,2}]/.a[[1]]];
V=FullSimplify[EI*D[y,{x,3}]/.a[[1]]];
(*Second Degree*)
y2=a2*x^2+a1*x+a0;
s=Solve[{(y2/.x-> 0)==0,(y2/.x->L)==0},{a0,a1}];
y2=y2/.s[[1]];
theta2=D[y2,x];
M2=EI*D[y2,{x,2}];
V2=EI*D[y2,{x,3}];
PE=EI/2*Integrate[(D[y2,{x,2}])^2,{x,0,L}]-Integrate[q*y2,{x,0,L}];
Eq1=D[PE,a2];
a=Solve[{Eq1==0},{a2}];
y2=y2/.a[[1]];
theta2=D[y2,x]/.a[[1]];
M2=FullSimplify[EI*D[y2,{x,2}]/.a[[1]]];
V2=FullSimplify[EI*D[y2,{x,3}]/.a[[1]]];
(*Third Degree*)
y3=a3*x^3+a2*x^2+a1*x+a0;
s=Solve[{(y3/.x-> 0)==0,(y3/.x->L)==0},{a0,a1}];
y3=y3/.s[[1]];
theta3=D[y3,x];
M3=EI*D[y3,{x,2}];
V3=EI*D[y3,{x,3}];
PE=EI/2*Integrate[(D[y3,{x,2}])^2,{x,0,L}]-Integrate[q*y3,{x,0,L}];
Eq1=D[PE,a2];
Eq2=D[PE,a3];
a=Solve[{Eq1==0,Eq2==0},{a2,a3}];
y3=y3/.a[[1]];
theta3=D[y3,x]/.a[[1]];
M3=FullSimplify[EI*D[y3,{x,2}]/.a[[1]]];
V3=FullSimplify[EI*D[y3,{x,3}]/.a[[1]]];
(*fourth Degree*)
y4=a4*x^4+a3*x^3+a2*x^2+a1*x+a0;
s=Solve[{(y4/.x-> 0)==0,(y4/.x->L)==0},{a0,a1}];
y4=y4/.s[[1]];
theta4=D[y4,x];
M4=EI*D[y4,{x,2}];
V4=EI*D[y4,{x,3}];
PE=EI/2*Integrate[(D[y4,{x,2}])^2,{x,0,L}]-Integrate[q*y4,{x,0,L}];
Eq1=D[PE,a2];
Eq2=D[PE,a3];
Eq3=D[PE,a4];
a=Solve[{Eq1==0,Eq2==0,Eq3==0},{a2,a3,a4}];
y4=y4/.a[[1]];
theta4=D[y4,x]/.a[[1]];
M4=FullSimplify[EI*D[y4,{x,2}]/.a[[1]]];
V4=FullSimplify[EI*D[y4,{x,3}]/.a[[1]]];
(*fifth Degree*)
y5=a5*x^5+a4*x^4+a3*x^3+a2*x^2+a1*x+a0;
s=Solve[{(y5/.x-> 0)==0,(y5/.x->L)==0},{a0,a1}];
y5=y5/.s[[1]];
theta4=D[y5,x];
M5=EI*D[y5,{x,2}];
V5=EI*D[y5,{x,3}];
PE=EI/2*Integrate[(D[y5,{x,2}])^2,{x,0,L}]-Integrate[q*y5,{x,0,L}];
Eq1=D[PE,a2];
Eq2=D[PE,a3];
Eq3=D[PE,a4];
Eq4=D[PE,a5];
a=Solve[{Eq1==0,Eq2==0,Eq3==0,Eq4==0},{a2,a3,a4,a5}];
y5=y5/.a[[1]];
theta5=D[y5,x]/.a[[1]];
M5=FullSimplify[EI*D[y5,{x,2}]/.a[[1]]];
V5=FullSimplify[EI*D[y5,{x,3}]/.a[[1]]];
EI = 200000*1000000*4*100000000/1000000000000;
q = -25*1000;
L = 10;
Plot[{y,y2,y4},{x,0,L},AxesLabel-> {"x (m)","y (m)"},PlotLegends->{Style["Exact y",Bold,12],Style["y2",Bold,12],Style["y4",Bold,12]}]
Plot[{theta,theta2,theta4},{x,0,L},AxesLabel-> {"x (m)","theta"},PlotLegends-> {Style["Exact theta",Bold,12],Style["theta 2",Bold,12],Style["theta 4",Bold,12]}]
Plot[{M,M2,M4},{x,0,L},AxesLabel-> {"x (m)","M (N.m.)"},PlotLegends-> {Style["Exact M",Bold,12],Style["M2",Bold,12],Style["M4",Bold,12]}]
Plot[{V,V2,V4},{x,0,L},AxesLabel-> {"x (m)","V (N)"},PlotLegends->{Style["Exact V",Bold,12],Style["V 2",Bold,12],Style["V4",Bold,12]}]


#### Example 3: Cantilever Beam with a Varying Cross Sectional Area

Let a beam with a length and with a constant width and a linearly varying height ( and ) be aligned with the coordinate axis . Assume that the beam has a fixed left end and had a shearing load acting downwards of 10kN on its right end. Find the displacement, bending moment, and shearing force on the beam by directly solving the differential equation of equilibrium and then using the Rayleigh Ritz method assuming polynomials of the degrees (0, 1, 2, 3, 4, 5, 6, 7). Assume the beam to be linear elastic with Young’s modulus and that the Euler Bernoulli Beam is an appropriate beam approximation. Compare the Rayleigh Ritz method with the exact solution.

##### Solution

Exact Solution:
First, the exact solution that would satisfy the equilibrium equations can be obtained. The equilibrium equation as shown in the Euler Bernoulli beam section apply only when and are constant. Since is variable, the differential equation has the form:

For the cantilever beam, . For consistency in the units, in all the following calculations and N. The moment of inertia is a function of as follows:

The exact solution can be obtained using Mathematica. The following are the four boundary conditions required:

Using Mathematica, the above differential equation can be solved to yield the following exact solution for :

The associated moment in N.m. and shearing force in N. are given by:

Obviously, as the beam is statically determinate, the equations for the moment and shear are very simple. However, the variable cross section leads to a complicated form for the displacement . Note that traditionally, in structural engineering applications, a constant cross section with the intermediate height of two thirds of the maximum height can be assumed to simplify the equations.

The Rayleigh Ritz Method:
The first step in the Rayleigh Ritz method finds the minimizer of the potential energy of the system which can be written as:

Notice that the potential energy lost by the action of the end force is equal to the product of ( is acting downwards and is assumed upwards) and the displacement evaluated at . To find an approximate solution, an assumption for the shape or the form of has to be introduced.
Polynomials of the Zero and First Degrees:
If we assume that is a constant (polynomial of the zero degree) or a linear (polynomial of the first degree) function, and when attempting to satisfy the essential boundary conditions:

this leads to the trivial solution , which will automatically be rejected.

Polynomial of the Second Degree:
The approximate solution forms for the displacement , the rotation , the moment , and the shear force functions if is assumed to be a polynomial of the second degree are:

To satisfy the essential boundary conditions, we have:

Therefore, the solutions forms have only one parameter that can be controlled:

Substituting into the equation of the potential energy of an Euler Bernoulli beam:

Note that is a function of and so it stays inside the integral. The unknown coefficient can be obtained by minimizing the potential energy:

Therefore, the “best” parabolic approximation for along with the corresponding solutions for and are given by:

Polynomial of the Third Degree:
The approximate solution forms for the displacement , the rotation , the moment , and the shear force functions if is assumed to be a polynomial of the third degree are:

To satisfy the essential boundary conditions, we have:

Therefore, the solutions forms have only two parameters and that can be controlled:

Substituting into the equation of the potential energy of an Euler Bernoulli beam:

The unknown coefficients and can be obtained by minimizing the potential energy:

Solving the above two equations yields:

Therefore, the “best” cubic approximation for along with the corresponding solutions for , , and are given by:

Polynomials of the Fourth Degree:
The approximate solution forms for the displacement , the rotation , the moment , and the shear force functions if is assumed to be a polynomial of the fourth degree are:

To satisfy the essential boundary conditions, we have:

Therefore, the solutions forms have the parameters , , and that can be controlled:

Substituting into the equation of the potential energy of an Euler Bernoulli beam:

The unknown coefficients , , and can be obtained by minimizing the potential energy:

Solving the above three equations yields:

Therefore, assuming a fourth order polynomial gives the following set of solutions:

Approximate solutions using higher order polynomials can be obtained similarly. The following plots show the convergence of the polynomial functions to the exact solution up to a polynomial of the sixth degree (Mathematica code is given below). In the first plot, it is clear that a polynomial of the second degree is capable of capturing the displacement quite accurately. However, the corresponding approximate solutions for the moment and shear are not as accurate. The accuracy of the approximate solution for the bending moment is higher than that for the shearing force and that is because the moment is related to the second derivative of while the shear is related to the third derivative of . It takes up to a polynomial of the seventh degree for for the approximate shearing force to have a flat distribution similar to the exact solution.

View Mathematica Code

Clear[y, b, L, t, Ii, Ee, P]
b = 1/4;
L = 8;
t = (1/2 - 1/4*X1/L);
Ii = b*t^3/12;
Ee = 20*10^9;
P = 10000;
a = DSolve[{D[Ee*Ii*y''[X1], {X1, 2}] == 0, y[0] == 0, y'[0] == 0, y''[L] == 0, (D[Ee*Ii, X1] /. X1 -> L)*y''[L] + (Ee*Ii /. X1 -> L)*y'''[L] == P}, y[X1], X1, Assumptions -> 0 <= X1 <= L]
y = FullSimplify[Chop[N[y[X1] /. a[[1]]]]]
th = D[y, X1];
M = FullSimplify[Ee*Ii*D[y, {X1, 2}]]
V = FullSimplify[D[M, X1]]

Plot[y, {X1, 0, L}, PlotLabel -> "Displacement y", AxesLabel -> {"X1 (m)", "y (m)"}, PlotLegends -> {"y exact"}]
Plot[M, {X1, 0, L}, PlotLabel -> "Moment M", AxesLabel -> {"X1 (m)", "M (N.m)"}, PlotLegends -> {"M exact"}]
Plot[V, {X1, 0, L}, PlotRange -> {{0, L}, {0, 2 P}}, PlotLabel -> "Shear V", AxesLabel -> {"X1 (m)", "V (N)"}, PlotLegends -> {"V exact"}]

Print["Second Order Polynomial"]
y2 = a2*X1^2;
d2y = D[y2, {X1, 2}];
PE = Integrate[Ee*Ii/2*d2y^2, {X1, 0, L}] - (-P)*y2 /. X1 -> L;
sol = Solve[D[PE, a2] == 0, a2]
y2 = y2 /. sol[[1]]
M2 = FullSimplify[Ee*Ii*D[y2, {X1, 2}]]
V2 = FullSimplify[D[M2, X1]]
Plot[{y, y2}, {X1, 0, L}, PlotLabel -> "Displacement y", AxesLabel -> {"X1 (m)", "y (m)"}, PlotLegends -> {"y exact", "y2"}]
Plot[{M, M2}, {X1, 0, L}, PlotLabel -> "Moment M", AxesLabel -> {"X1 (m)", "M (N.m)"}, PlotLegends -> {"M exact", "M2"}]
Plot[{V, V2}, {X1, 0, L}, PlotRange -> {{0, L}, {0, 2 P}}, PlotLabel -> "Shear V", AxesLabel -> {"X1 (m)", "V (N)"}, PlotLegends -> {"V exact", "V2"}]

Print["Third Order Polynomial"]
y3 = a2*X1^2 + a3*X1^3;
d2y = D[y3, {X1, 2}];
PE = Integrate[Ee*Ii/2*d2y^2, {X1, 0, L}] - (-P)*y3 /. X1 -> L;
sol = Solve[{D[PE, a2] == 0, D[PE, a3] == 0}, {a2, a3}]
y3 = y3 /. sol[[1]]
M3 = FullSimplify[Ee*Ii*D[y3, {X1, 2}]]
V3 = FullSimplify[D[M3, X1]]
Plot[{y, y3}, {X1, 0, L}, PlotLabel -> "Displacement y", AxesLabel -> {"X1 (m)", "y (m)"}, PlotLegends -> {"y exact", "y3"}]
Plot[{M, M3}, {X1, 0, L}, PlotLabel -> "Moment M", AxesLabel -> {"X1 (m)", "M (N.m)"}, PlotLegends -> {"M exact", "M3"}]
Plot[{V, V3}, {X1, 0, L}, PlotRange -> {{0, L}, {0, 2 P}}, PlotLabel -> "Shear V", AxesLabel -> {"X1 (m)", "V (N)"},  PlotLegends -> {"V exact", "V3"}]

Print["Fourth Order Polynomial"]
y4 = a2*X1^2 + a3*X1^3 + a4*X1^4;
d2y = D[y4, {X1, 2}];
PE = Integrate[Ee*Ii/2*d2y^2, {X1, 0, L}] - (-P)*y4 /. X1 -> L;
sol = Solve[{D[PE, a2] == 0, D[PE, a3] == 0, D[PE, a4] == 0}, {a2, a3, a4}]
y4 = y4 /. sol[[1]]
M4 = FullSimplify[Ee*Ii*D[y4, {X1, 2}]]
V4 = FullSimplify[D[M4, X1]]
Plot[{y, y4}, {X1, 0, L}, PlotLabel -> "Displacement y", AxesLabel -> {"X1 (m)", "y (m)"}, PlotLegends -> {"y exact", "y4"}]
Plot[{M, M4}, {X1, 0, L}, PlotLabel -> "Moment M", AxesLabel -> {"X1 (m)", "M (N.m)"}, PlotLegends -> {"M exact", "M4"}]
Plot[{V, V4}, {X1, 0, L}, PlotRange -> {{0, L}, {0, 2 P}}, PlotLabel -> "Shear V", AxesLabel -> {"X1 (m)", "V (N)"}, PlotLegends -> {"V exact", "V4"}]

Print["Fifth Order Polynomial"]
y5 = a2*X1^2 + a3*X1^3 + a4*X1^4 + a5*X1^5;
d2y = D[y5, {X1, 2}];
PE = Integrate[Ee*Ii/2*d2y^2, {X1, 0, L}] - (-P)*y5 /. X1 -> L;
sol = Solve[{D[PE, a2] == 0, D[PE, a3] == 0, D[PE, a4] == 0, D[PE, a5] == 0}, {a2, a3, a4, a5}]
y5 = y5 /. sol[[1]]
M5 = FullSimplify[Ee*Ii*D[y5, {X1, 2}]]
V5 = FullSimplify[D[M5, X1]]
Plot[{y, y5}, {X1, 0, L}, PlotLabel -> "Displacement y", AxesLabel -> {"X1 (m)", "y (m)"}, PlotLegends -> {"y exact", "y5"}]
Plot[{M, M5}, {X1, 0, L}, PlotLabel -> "Moment M",  AxesLabel -> {"X1 (m)", "M (N.m)"}, PlotLegends -> {"M exact", "M5"}]
Plot[{V, V5}, {X1, 0, L}, PlotRange -> {{0, L}, {0, 2 P}}, PlotLabel -> "Shear V", AxesLabel -> {"X1 (m)", "V (N)"}, PlotLegends -> {"V exact", "V5"}]

Print["Sixth Order Polynomial"]
y6 = a2*X1^2 + a3*X1^3 + a4*X1^4 + a5*X1^5 + a6*X1^6;
d2y = D[y6, {X1, 2}];
PE = Integrate[Ee*Ii/2*d2y^2, {X1, 0, L}] - (-P)*y6 /. X1 -> L;
sol = Solve[{D[PE, a2] == 0, D[PE, a3] == 0, D[PE, a4] == 0, D[PE, a5] == 0, D[PE, a6] == 0}, {a2, a3, a4, a5, a6}]
y6 = y6 /. sol[[1]]
M6 = FullSimplify[Ee*Ii*D[y6, {X1, 2}]]
V6 = FullSimplify[D[M6, X1]]
Plot[{y, y6}, {X1, 0, L}, PlotLabel -> "Displacement y",  AxesLabel -> {"X1 (m)", "y (m)"}, PlotLegends -> {"y exact", "y6"}]
Plot[{M, M6}, {X1, 0, L}, PlotLabel -> "Moment M",  AxesLabel -> {"X1 (m)", "M (N.m)"}, PlotLegends -> {"M exact", "M6"}]
Plot[{V, V6}, {X1, 0, L}, PlotRange -> {{0, L}, {0, 2 P}},  PlotLabel -> "Shear V", AxesLabel -> {"X1 (m)", "V (N)"},  PlotLegends -> {"V exact", "V6"}]

Print["Seventh Order Polynomial"]
y7 = a2*X1^2 + a3*X1^3 + a4*X1^4 + a5*X1^5 + a6*X1^6 + a7*X1^7;
d2y = D[y7, {X1, 2}];
PE = Integrate[Ee*Ii/2*d2y^2, {X1, 0, L}] - (-P)*y7 /. X1 -> L;
sol = Solve[{D[PE, a2] == 0, D[PE, a3] == 0, D[PE, a4] == 0, D[PE, a5] == 0, D[PE, a6] == 0, D[PE, a7] == 0}, {a2, a3, a4, a5,a6, a7}]
y7 = y7 /. sol[[1]]
M7 = FullSimplify[Ee*Ii*D[y7, {X1, 2}]]
V7 = FullSimplify[D[M7, X1]]
Plot[{y, y7}, {X1, 0, L}, PlotLabel -> "Displacement y", AxesLabel -> {"X1 (m)", "y (m)"}, PlotLegends -> {"y exact", "y7"}]
Plot[{M, M7}, {X1, 0, L}, PlotLabel -> "Moment M",  AxesLabel -> {"X1 (m)", "M (N.m)"}, PlotLegends -> {"M exact", "M7"}]
Plot[{V, V7}, {X1, 0, L}, PlotRange -> {{0, L}, {0, 2 P}},  PlotLabel -> "Shear V", AxesLabel -> {"X1 (m)", "V (N)"}, PlotLegends -> {"V exact", "V7"}]

Plot[{y, y2, y3, y4, y5, y6, y7}, {X1, 0, L},  PlotLabel -> "Displacement y", AxesLabel -> {"X1 (m)", "y (m)"},  PlotLegends -> {"y exact", "y2", "y3", "y4", "y5", "y6", "y7"}]
Plot[{M, M2, M3, M4, M5, M6, M7}, {X1, 0, L}, PlotLabel -> "Moment M",  AxesLabel -> {"X1 (m)", "M (N.m)"},  PlotLegends -> {"M exact", "M2", "M3", "M4", "M5", "M6", "M7"}]
Plot[{V,V2,V3,V4,V5,V6,V7}, {X1, 0, L}, PlotRange ->{{0, L}, {0, 2 P}},PlotLabel->"Shear V",AxesLabel -> {"X1 (m)", "V (N)"},PlotLegends -> {"V exact", "V2", "V3", "V4", "V5", "V6", "V7"}]


### Problems

1. The exact displacement in meters of the shown Euler Bernoulli beam follows the function:

The beam’s Young’s modulus and moment of inertia are and .

1. Find the strain energy stored in the beam (Answer: 21093.8 N.m.).
2. Use the Rayleigh Ritz method to find approximate solutions for the displacement across the whole beam. Assume the approximations to be polynomials of the zero, first, second, third, fourth, fifth, and sixth degrees.
3. Plot the exact solution versus the approximate solutions for , , , and . Comment on the results.
2. For the following two linear elastic isotropic small deformations beam structures:

1. Find the exact solution of the displacement.
2. Find an approximate solution using the Rayleigh Ritz method with polynomial trial functions of zero, first, second, third, and fourth degrees satisfying the essential boundary conditions. Comment on the difference between the approximate and the exact solutions.
3. An Euler Bernoulli beam of length with both ends fixed is loaded by a concentrated force at the centre of the beam. Assume that the beam is made out of a linear elastic isotropic material and that the deformations are small. If is Young’s modulus and is the moment of inertia, then find:
1. the strain energy in terms of the displacement function .
2. The expression for the potential energy of the system.
3. Show that the following series satisfies the essential boundary conditions

where and are constants

4. Take one term and two terms from the series above and determine the constants using the Rayleigh Ritz method.
5. Find the exact solution and compare with the approximate solutions obtained using the Rayleigh Ritz method.
4. For the shown two beam structures

1. Find the exact solution for the displacement.
2. Use the Rayleigh Ritz method with polynomials of the zero, one, two, three, four, five, and six degrees to find an approximate solution for the displacement. For the beam under axial loading compare the stresses with the exact solution. For the beam under lateral loading, compare the rotation, moment, and shear with the corresponding exact solutions.
5. The shown beam under axial loading is subjected to the varying body force given per unit volume. Assume that the area varies linearly across the length of the structure.

1. Find the exact displacement by solving the differential equation of equilibrium for bars under axial loading.
2. Use the Rayleigh Ritz method to find a polynomial approximation of the zero, first, second, and third degrees for the displacement function.
6. The shown plate has a thickness . The plate is in a plane stress condition. The left boundary where has zero vertical and horizontal displacements. The material is linear elastic with small deformations and Young’s modulus and Poisson’s ratio are equal to 200 GPa and 0.3, respectively. The right boundary is subjected to a constant normal tensile stress of 20MPa while the bottom boundary is subjected to a normal compressive stress that varies linearly with a maximum value of 20MPa as shown in the figure below. Using the Rayleigh Ritz method and assuming that the displacement of the plate can be approximated using the function:

1. Utilize the essential boundary conditions to reduce the number of unknown constants in the displacement function.
2. Find the infinitesimal strain tensor in terms of the remaining unknown constants.
3. Write the expression of the potential energy of the system in terms of the remaining unknown constants.
4. Find the unknown constants using the Rayleigh Ritz method.
5. Comment on how accurate the above displacement function is in approximating the exact displacement of the plate.

I was looking around for Rayleigh-Ritz examples for my ME 512 class (FEA I) at the University of Louisville and I found your page. This is an excellent set of examples! Have you put the contents of this and the other pages into book form?

Thanks!

Associate Professor
Mechanical Engineering
University of Louisville

Yes. Thank you for your interest!
There is a book published by Kendall Hunt “https://www.kendallhunt.com/store-product.aspx?id=108235”, but the website is more up to date with more in-depth information in various sections.

2. zack says:

Where can we find the solutions of the problems at the end? Thanks

Email me if you need solutions for a particular problem and I will email you back if I have solutions.

1. zack says:

3. Saqib Ali says:

Hi Samer, Thanks for such in-depth information. May I ask, Can you send me the worked solutions for probelms 5 & 6?

Hello,

I am wondering if you could send me the worked out solutions to problem 1?

What I am actually looking for is an example on the deflection of a fully fixed beam with a non-centered force acting on it (as in problem 1), but it also has a changing cross-section of three different moment of inertias. But this is the closest to this I could find!

If you happen to know of any such example I would certainly be appreciative.

Thank you

5. Gamal Elsayed says:

Thanks for this great and clear presentation of the Rayleigh-Ritz method. Can you kindly provide me with the solution for problems 4 and 5? I would like to compare my solution to yours.

6. Yuanping Li says: